映像处理：
/Get-MountedImageInfo - 显示有关安装的 WIM 和 VHD 映像的信息。
/Get-ImageInfo - 显示有关 WIM 或 VHD 文件中映像的信息。
/Commit-Image - 保存对装载的 WIM 或 VHD 映像的更改。
/Unmount-Image - 卸载已装载的 WIM 或 VHD 映像。
/Mount-Image - 从 WIM 或 VHD 文件装载映像。
/Remount-Image - 恢复孤立的映像装载目录。
/Cleanup-Mountpoints - 删除与损坏的已安装映像关联的资源。

 对WIM进行编辑:
/List-Image - 显示指定映像中的文件和文件夹的列表。
/Delete-Image - 在具有多个卷映像的 WIM 文件中删除指定的卷映像。
/Split-Image - 将现有 .wim 文件拆分为多个只读 WIM (SWM)拆分文件。
/Export-Image - 将指定映像的副本导出到其他文件。
/Append-Image - 将新映像添加到 WIM 文件中。
/Capture-Image - 将驱动器的映像捕获到新的 WIM 文件中。
/Apply-Image - 应用一个映像。
/Get-MountedWimInfo - 显示显示挂载的 WIM 映像的信息。
/Get-WimInfo - 显示有关 WIM 文件中的映像的信息。
/Commit-Wim - 保存对挂载的 WIM 映像的更改。
/Unmount-Wim - 卸载挂载的 WIM 映像。
/Mount-Wim - 从 WIM 文件挂载映像。
/Remount-Wim - 恢复孤立的 WIM 挂载目录。
/Cleanup-Wim - 删除损坏的WIM映像关联的挂载资源。

相关实例：




@ECHO OFF&(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(
powershell -Command "Start-Process '%~sdpnx0' -Verb RunAs"&&EXIT)
title 制作多合一  Windows  系统镜像
rem 确认管理员权限
Rd "%WinDir%\system32\test_permissions" >NUL 2>NUL
Md "%WinDir%\System32\test_permissions" 2>NUL||(Echo 没有管理员权限，自动退出！&&PAUSE >NUL&&EXIT)
Rd "%WinDir%\System32\test_permissions" 2>NUL

rem 设置工作文件夹和镜像文件位置，更新存放位置，请自行修改
set WorkPath="D:\Temp\win11"
set UpPath="%WorkPath%\Update"
set WimFile="G:\sources\install.esd"

rem 判断工作文件夹，镜像文件，更新包文件夹是否存在，不存在就退出
IF NOT EXIST "%WorkPath%" (Echo 工作文件夹不存在，自动退出！&&PAUSE >NUL&&EXIT)
IF NOT EXIST "%WimFile%" (Echo 镜像不存在，自动退出！&&PAUSE >NUL&&EXIT)
IF NOT EXIST "%UpPath%" (Echo 更新文件夹不存在，自动退出！&&PAUSE >NUL&&EXIT)

echo.
echo  -----== 制作多合一  Windows  系统镜像 ==-----
echo.
echo           工作文件夹：%WorkPath%
echo           更新保存位置：%UpPath%
echo           系统镜像位置：%WimFile%
echo.

rem 切换到工作路径
CD /D  %WorkPath%

rem 获取 Windows 的映像信息，保存到D:\Win11Info.txt文件中，备忘，已注释，单纯为了复制镜像名称到下面的索引中。
rem dism /get-wiminfo /wimfile:G:\sources\install.esd >D:\Win11Info.txt

rem 为3个系统镜像对应创建3个文件夹，更多个镜像请参照添加（每行2处）
IF NOT EXIST "%WorkPath%\1" (MD "%WorkPath%\1")
IF NOT EXIST "%WorkPath%\2" (MD "%WorkPath%\2")
IF NOT EXIST "%WorkPath%\3" (MD "%WorkPath%\3")

rem 设置镜像索引名称，更多个索引请参照修改和添加（每行1处）
set Index1="Windows 11 Enterprise LTSC"
set Index2="Windows 11 IoT Enterprise LTSC"
set Index3="Windows 11 IoT Enterprise Subscription LTSC"

echo.
echo           正在释放系统镜像，请稍候...
echo.
rem 释放各系统映像，更多个镜像请参照添加（每行2处）
DISM.exe /Apply-Image /ImageFile:%WimFile% /Index:1 /ApplyDir:%WorkPath%\1
DISM.exe /Apply-Image /ImageFile:%WimFile% /Index:2 /ApplyDir:%WorkPath%\2
DISM.exe /Apply-Image /ImageFile:%WimFile% /Index:3 /ApplyDir:%WorkPath%\3

echo.
echo           正在应用积累更新，请稍候...
echo.
rem 为系统映像应用积累更新，更多个镜像请参照添加（每行1处）
DISM.exe /Image:%WorkPath%\1 /Add-Package /PackagePath:%UpPath%
DISM.exe /Image:%WorkPath%\2 /Add-Package /PackagePath:%UpPath%
DISM.exe /Image:%WorkPath%\3 /Add-Package /PackagePath:%UpPath%

echo.
echo           正在清理和重置被替换的WinSxS组件以减小映像体积，请稍候...
echo.
rem 清理和重置被替换的WinSxS组件以减小映像体积，更多个镜像请参照添加（每行1处）
DISM.exe /Image:%WorkPath%\1 /Cleanup-Image /StartComponentCleanup /ResetBase
DISM.exe /Image:%WorkPath%\2 /Cleanup-Image /StartComponentCleanup /ResetBase
DISM.exe /Image:%WorkPath%\3 /Cleanup-Image /StartComponentCleanup /ResetBase

echo.
echo           正在将各映像按顺序打包到同一个新的“install.wim”文件里，请稍候...
echo.
rem 将各映像按顺序打包到同一个新的“install.wim”文件里，更多个镜像请参照添加（每行3处）
DISM.exe /Capture-Image /ImageFile:%WorkPath%\install.wim /CaptureDir:%WorkPath%\1 /Name:%Index1% /Description:%Index1% /Compress:none
DISM.exe /Append-Image /ImageFile:%WorkPath%\install.wim /CaptureDir:%WorkPath%\2 /Name:%Index2% /Description:%Index2%
DISM.exe /Append-Image /ImageFile:%WorkPath%\install.wim /CaptureDir:%WorkPath%\3 /Name:%Index3% /Description:%Index3%

echo.
echo           正在重新输出并压缩成极限压缩的“install.esd”文件，请稍候...
echo.
rem 将新的“install.wim”文件重新输出并压缩成极限压缩的“install.esd”，以保证ISO文件体积减到最小，更多个镜像请参照添加（每行1处）
DISM.exe /Export-Image /SourceImageFile:%WorkPath%\install.wim /SourceIndex:1 /DestinationImageFile:%WorkPath%\install.esd /Compress:recovery
DISM.exe /Export-Image /SourceImageFile:%WorkPath%\install.wim /SourceIndex:2 /DestinationImageFile:%WorkPath%\install.esd /Compress:recovery
DISM.exe /Export-Image /SourceImageFile:%WorkPath%\install.wim /SourceIndex:3 /DestinationImageFile:%WorkPath%\install.esd /Compress:recovery

echo.
echo           正在清理镜像释放的文件夹，请稍候...
echo.
rem 清理镜像释放的文件夹，更多个镜像请参照添加（每行2处）
DEL "%WorkPath%\1" /F /S /Q&&RD "%WorkPath%\1" /S /Q
DEL "%WorkPath%\2" /F /S /Q&&RD "%WorkPath%\2" /S /Q
DEL "%WorkPath%\3" /F /S /Q&&RD "%WorkPath%\3" /S /Q

echo.
echo  -----== 清理完成，全部工作结束，按任意键退出或者直接关闭窗口 ==-----
pause.
@echo on